'분류 전체보기' 카테고리의 글 목록 (2 Page)

분류 전체보기

UIComponent Button 04

2015. 12. 16. 16:35

다른 도메인간의 네트워크 작업시 아래와 같은 정책파일이 필요한데 이 파일의 이름은 crossdomain.xml이어야 하며 접근하고자 하는 파일의 엑세스를 허용하는 도메인 주소를 나열하는 형식을 이용한다. 도메인 루트 최상단에 위치시키면 (가장 낮은 단계의 보안) swf파일이 실행되면서 특별한 명령없이도 자동적으로 로드되지만 필요에 따라 임의의 위치에 저장 후 Security.loadPolicyFile("url") 메서드를 이용, 명시적으로 정책파일을 로드하기도 한다.

crossdomain.xml

ButtonTest_09.as

package {
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.display.Loader;
	import flash.display.Bitmap;
	
	import flash.events.Event;
	import flash.events.ProgressEvent;
	import flash.events.IOErrorEvent;
	import flash.events.SecurityErrorEvent;
	
	import fl.controls.Button;
	import flash.net.URLRequest;
	import flash.system.LoaderContext;
	import flash.system.ApplicationDomain;
	
	[SWF(backgroundColor = "#A5D0DE", width = "550", height = "300", frameRate = "12")]
	
	public class ButtonTest_09 extends Sprite {
		
		private var button:Button;
		private var loader:Loader;
		
		private static var domain:String = "http://domain/bitmaps/twitter.png";
		
		public function ButtonTest_09() {
			stage.showDefaultContextMenu = false;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			button = new Button();
			button.setSize(300, 100);
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			button.label = "loading bitmap... ";
			addChild(button);
			
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompletedEvent);
			loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			loader.contentLoaderInfo.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError)
			loadContent();
		}
		
		private function loadContent():void {
			var context:LoaderContext = new LoaderContext();
			context.checkPolicyFile = true;
			context.applicationDomain = ApplicationDomain.currentDomain;
			loader.load(new URLRequest(domain), context);
		}

		private function unloadContent():void {
			loader.unload();
			removeListeners();
		}

		private function removeListeners():void {
			loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onCompletedEvent); 
			loader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			loader.contentLoaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			loader.contentLoaderInfo.removeEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError)
		}
		
		private function onProgressEvent(event:ProgressEvent):void {
			button.label = "loading bitmap... ";
		}
		
		private function onIOErrorEvent(event:IOErrorEvent):void {
			button.label = "URL NotFount";
			unloadContent();
		}
		
		private function onSecurityError(event:SecurityErrorEvent):void {
			button.label = "Security Error";
			unloadContent();
		}
		
		private function onCompletedEvent(event:Event):void {
			var logo:Bitmap = loader.content as Bitmap;
			logo.width =  50;
			logo.height = 50;
			logo.smoothing = true;
			
			button.label = "Twitter";
			button.setStyle("icon", logo);
			button.invalidate();
			
			removeListeners();
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

ButtonTest_10.as

package {
	
	import flash.display.Sprite;
	import flash.display.Loader;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.events.ProgressEvent;
	import flash.events.IOErrorEvent;
	import flash.events.SecurityErrorEvent;
	
	import flash.text.Font;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.GridFitType;
	import flash.text.AntiAliasType;
	
	import fl.controls.Button;
	import fl.controls.ProgressBar;
	import fl.controls.ProgressBarMode;
	
	import flash.net.URLRequest;
	import flash.utils.getDefinitionByName;
	
	import flash.system.Security;
	import flash.system.LoaderContext;
	import flash.system.SecurityDomain;
	import flash.system.ApplicationDomain;
	
	[SWF(backgroundColor = "#A5D0DE", width = "550", height = "300", frameRate = "12")]
	
	public class ButtonTest_10 extends Sprite {
		
		private var button:Button;
		private var loader:Loader;
		private var progressBar:ProgressBar;
		
		private var font:Font;
		private var fontName:String;
		private var txtField:TextField;
		
		private static var url:String = "http://domain/fonts/chinese_01.swf";
		private static var className:String = "Chinese01";
		
		public function ButtonTest_10() {
			stage.showDefaultContextMenu = false;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			button = new Button();
			button.setSize(300, 100);
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			button.label = "Press the button to load icon";
			button.drawNow();
			addChild(button);
			
			button.addEventListener(MouseEvent.CLICK, onMouseClick);
		}
		
		private function onMouseClick(event:MouseEvent):void {
			progressBar = new ProgressBar();
			progressBar.setSize(150, 4);
			progressBar.mode = ProgressBarMode.MANUAL;
			
			button.label = "0%";
			button.setStyle("icon", progressBar);
			button.validateNow();
			button.removeEventListener(MouseEvent.CLICK, onMouseClick);
			
			loadContent();
		}
		
		private function loadContent():void {
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompletedEvent);
			loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			loader.contentLoaderInfo.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
			try {
				var context:LoaderContext = new LoaderContext();
				context.securityDomain = SecurityDomain.currentDomain;
				context.applicationDomain = ApplicationDomain.currentDomain;
				loader.load(new URLRequest(url), context);
			} catch (err:Error) {
				trace(err.message);
			}
		}
		
		private function unloadContent():void {
			loader.unload();
			removeListeners();
		}
		
		private function removeListeners():void {
			loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onCompletedEvent);
			loader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			loader.contentLoaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			loader.contentLoaderInfo.removeEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
		}
		
		private function onProgressEvent(event:ProgressEvent):void {
			var percent:Number = Math.round(event.bytesLoaded / event.bytesTotal * 100);
			button.label = percent + "%";
			progressBar.setProgress(event.bytesLoaded, event.bytesTotal);
			progressBar.drawNow();
		}
		
		private function onIOErrorEvent(event:IOErrorEvent):void {
			unloadContent();
			button.label = "URL NotFount";
		}
		
		private function onSecurityError(event:SecurityErrorEvent):void {
			unloadContent();
			button.label = "SecurityError";
		}
		
		private function onCompletedEvent(event:Event):void {
			removeListeners();
			
			var FontClass:Class = getDefinitionByName(className) as Class;
			Font.registerFont(FontClass);
			font = new FontClass() as Font;
			fontName = font.fontName;
			
			createTextField();
		}
		
		private function createTextField():void {
			var txtFormat:TextFormat = new TextFormat();
			txtFormat.size = 46;
			txtFormat.color = 0x000000;
			txtFormat.font = font.fontName;
			txtFormat.kerning = true;
			txtFormat.letterSpacing = -4;
			
			txtField = new TextField();
			txtField.embedFonts = true;
			txtField.autoSize = TextFieldAutoSize.LEFT;
			txtField.antiAliasType = AntiAliasType.ADVANCED;
			txtField.gridFitType = GridFitType.PIXEL;
			txtField.defaultTextFormat = txtFormat;
			txtField.text = "按钮";
			
			setButton();
		}
		
		private function setButton():void {
			button.label = "";
			button.setStyle("icon", txtField);
			button.validateNow();
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

ButtonTest_11.as

package {
	
	import flash.display.Sprite;
	import flash.display.Loader;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.events.ProgressEvent;
	import flash.events.IOErrorEvent;
	import flash.events.SecurityErrorEvent;
	
	import flash.text.Font;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.GridFitType;
	import flash.text.AntiAliasType;
	
	import fl.controls.Button;
	import fl.controls.ProgressBar;
	import fl.controls.ProgressBarMode;
	
	import flash.net.URLRequest;
	import flash.utils.getDefinitionByName;
	
	import flash.system.Security;
	import flash.system.LoaderContext;
	import flash.system.SecurityDomain;
	import flash.system.ApplicationDomain;
	
	[SWF(backgroundColor = "#A5D0DE", width = "550", height = "300", frameRate = "30")]
	
	public class ButtonTest_11 extends Sprite {
		
		private var button:Button;
		private var loader:Loader;
		private var progressBar:ProgressBar;
		
		private var font:Font;
		private var fontName:String;
		private var txtField:TextField;
		
		private static var url:String = "http://domain/fonts/deejaySupreme.swf";
		private static var className:String = "DeejaySupreme";
		
		public function ButtonTest_11() {
			stage.showDefaultContextMenu = false;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			button = new Button();
			button.setSize(300, 100);
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			button.label = "Press the button to load icon";
			button.drawNow();
			addChild(button);
			
			button.addEventListener(MouseEvent.CLICK, onMouseClick);
		}
		
		private function onMouseClick(event:MouseEvent):void {
			progressBar = new ProgressBar();
			progressBar.setSize(150, 4);
			progressBar.mode = ProgressBarMode.POLLED;
			
			button.label = "0%";
			button.setStyle("icon", progressBar);
			button.validateNow();
			button.removeEventListener(MouseEvent.CLICK, onMouseClick);
			
			loadContent();
		}
		
		private function loadContent():void {
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompletedEvent);
			loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			loader.contentLoaderInfo.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
			try {
				var context:LoaderContext = new LoaderContext();
				context.securityDomain = SecurityDomain.currentDomain;
				context.applicationDomain = ApplicationDomain.currentDomain;
				loader.load(new URLRequest(url), context);
			} catch (err:Error) {
				trace(err.message);
			}
		}
		
		private function unloadContent():void {
			loader.unload();
			removeListeners();
		}
		
		private function removeListeners():void {
			loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onCompletedEvent);
			loader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			loader.contentLoaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			loader.contentLoaderInfo.removeEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
		}
		
		private function onProgressEvent(event:ProgressEvent):void {
			var percent:Number = Math.round(event.bytesLoaded / event.bytesTotal * 100);
			button.label = percent + "%";
			progressBar.setProgress(event.bytesLoaded, event.bytesTotal);
			progressBar.drawNow();
		}
		
		private function onIOErrorEvent(event:IOErrorEvent):void {
			unloadContent();
			button.label = "URL NotFount";
		}
		
		private function onSecurityError(event:SecurityErrorEvent):void {
			unloadContent();
			button.label = "SecurityError";
		}
		
		private function onCompletedEvent(event:Event):void {
			removeListeners();
			button.clearStyle("icon");
			button.invalidate();
			
			var FontClass:Class = getDefinitionByName(className) as Class;
			Font.registerFont(FontClass);
			font = new FontClass() as Font;
			fontName = font.fontName;
			
			createTextField();
		}
		
		private function createTextField():void {
			var txtFormat:TextFormat = new TextFormat();
			txtFormat.size = 90;
			txtFormat.color = 0x333333;
			txtFormat.font = font.fontName;
			
			txtField = new TextField();
			txtField.embedFonts = true;
			txtField.autoSize = TextFieldAutoSize.LEFT;
			txtField.antiAliasType = AntiAliasType.NORMAL;
			txtField.gridFitType = GridFitType.PIXEL;
			txtField.defaultTextFormat = txtFormat;
			txtField.text = "'";
			
			setButton();
		}
		
		private function setButton():void {
			var txtFormat:TextFormat = new TextFormat();
			txtFormat.font = "century schoolbook, georgia, sans-serif";
			txtFormat.italic = true;
			txtFormat.bold = true;
			txtFormat.size = 16;
			txtFormat.color = 0x333333;
			
			button.label = "“be water, friends”";
			button.setStyle("icon", txtField);
			button.setStyle("textFormat", txtFormat);
			button.validateNow();
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

UIComponent Button 03

2015. 12. 13. 18:29

ButtonTest_06.as

package {
	
	import flash.display.Sprite;
	import flash.display.StageScaleMode;
	import flash.display.StageAlign;
	
	import fl.controls.Button;
	
	[SWF(backgroundColor = "#A5D0DE", width = "550", height = "300", frameRate = "12")]
	
	public class ButtonTest_06 extends Sprite {
		
		private var button:Button;
		
		public function ButtonTest_06() {
			stage.showDefaultContextMenu = false;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			button = new Button();
			button.setSize(300, 100);
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			button.label = "Warner Bros";
			addChild(button);
			
			/*
			라이브러리 자원 활용
			*/
			var logo:Sprite = new WarnerBros();
			logo.scaleX = 0.4;
			logo.scaleY = 0.4;
			
			button.setStyle("icon", logo);
			button.validateNow();
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

ButtonTest_07.as

package {
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.display.MovieClip;
	import flash.display.Loader;
	import flash.display.DisplayObject;
	
	import flash.events.Event;
	import flash.events.ProgressEvent;
	import flash.events.IOErrorEvent;
	
	import fl.controls.Button;
	import flash.net.URLRequest;
	import flash.system.ApplicationDomain;
	
	[SWF(backgroundColor = "#A5D0DE", width = "550", height = "300", frameRate = "12")]
	
	public class ButtonTest_07 extends Sprite {
		
		private var button:Button;
		private var loader:Loader;
		
		private static var className:String = "MTV";
		private static var domain:String = "http://YourDomain/logos.swf";
		
		public function ButtonTest_07() {
			stage.showDefaultContextMenu = false;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			button = new Button();
			button.setSize(300, 100);
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			button.label = "MTV International";
			addChild(button);
			
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompletedEvent, false, 0, true);
			loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, onProgressEvent, false, 0, true);
			loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent, false, 0, true);
			loader.load(new URLRequest(domain));
		}
		
		private function onProgressEvent(event:ProgressEvent):void {
			txtLoadInfo.text = "loading... ";
		}
		
		private function onIOErrorEvent(event:IOErrorEvent):void {
			event.target.removeEventListener(Event.COMPLETE, onCompletedEvent); 
			event.target.removeEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			event.target.removeEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			txtLoadInfo.text = "URL NotFount";
		}
		
		private function onCompletedEvent(event:Event):void {
			event.target.removeEventListener(Event.COMPLETE, onCompletedEvent); 
			event.target.removeEventListener(ProgressEvent.PROGRESS, onProgressEvent);
			event.target.removeEventListener(IOErrorEvent.IO_ERROR, onIOErrorEvent);
			
			/*
			외부 라이브러리 자원 활용
			*/
			var ClassReference:Class = event.target.applicationDomain.getDefinition(className) as Class;
			var logo:DisplayObject = new ClassReference();
			
			button.setStyle("icon", logo);
			button.invalidate();
			txtLoadInfo.text = "load completed... ";
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

ButtonTest_07.as

package {
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.display.MovieClip;
	
	import fl.controls.Button;
	
	[SWF(backgroundColor = "#A5D0DE", width = "550", height = "300", frameRate = "12")]
	
	public class ButtonTest_08 extends Sprite {
		
		[Embed(source = "amnesty.swf")]
		private var AssetClass:Class;
		private var asset:MovieClip;
		
		public function ButtonTest_08() {
			stage.showDefaultContextMenu = false;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			
			var button:Button = new Button();
			button.setSize(300, 100);
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			button.label = "Amnesty\nInternational";
			addChild(button);
			
			asset = new AssetClass();
			
			button.setStyle("icon", asset);
			button.invalidate();
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

UIComponent Button 02

2015. 12. 11. 16:57

ButtonTest_04.as

package {
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;

	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextFormat;

	import fl.controls.Button;
	import fl.managers.StyleManager;
	
	[SWF(backgroundColor = "#B4DCEB", width = "400", height = "150", frameRate = "12")]
	
	public class ButtonTest_04 extends Sprite {
		
		public function ButtonTest_04() {
			stage.showDefaultContextMenu = false;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			
			var format:TextFormat = new TextFormat();
			format.size = 11;
			format.font = "Arial";
			
			for (var i:int = 0; i < 2; i++) {
				var button:Button = new Button();
				button.label = "button " + (i + 1);
				button.x = 80 + i * 140;
				button.y = 64;
				button.addEventListener(MouseEvent.MOUSE_OVER, overHandler, false, 0, true);
				button.addEventListener(MouseEvent.MOUSE_OUT, outHandler, false, 0, true);
				addChild(button);
			}
			
			StyleManager.setComponentStyle(Button,"textFormat", format);
		}
		
		private function overHandler(event:MouseEvent):void {
			event.target.emphasized = true;
		}
		
		private function outHandler(event:MouseEvent):void {
			event.target.emphasized = false;
		}
	}
}

ButtonTest_05.as

package {
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;

	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextFormat;

	import fl.controls.Slider;
	import fl.controls.Button;
	import fl.events.SliderEvent;
	import fl.managers.StyleManager;
	
	[SWF(backgroundColor = "#B4DCEB", width = "400", height = "150", frameRate = "12")]
	
	public class ButtonTest_05 extends Sprite {
		
		private var slider:Slider;
		private var button:Button;
		
		public function ButtonTest_05() {
			stage.showDefaultContextMenu = false;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			
			var style:Object = Button.getStyleDefinition();
			var emphasizedPadding:uint = style.emphasizedPadding;
			
			button = new Button();
			button.label = "emphasized padding: " + emphasizedPadding;
			button.emphasized = true;
			button.width = 150;
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height) - 15;
			addChild(button);
			
			slider = new Slider();
			slider.tickInterval = 1;
			slider.snapInterval = 1;
			slider.liveDragging = true;
			slider.value = emphasizedPadding;
			slider.width = 150;
			slider.x = centerAlign(stage.stageWidth, slider.width);
			slider.y = centerAlign(stage.stageHeight, slider.height) + 15;
			slider.addEventListener(SliderEvent.CHANGE, onChangeEvent, false, 0, true);
			addChild(slider);
			
			var format:TextFormat = new TextFormat();
			format.size = 11;
			format.font = "Arial";
			
			StyleManager.setComponentStyle(Button,"textFormat", format);
		}
		
		private function onChangeEvent(event:SliderEvent):void {
			button.label = "emphasized padding: " + event.value;
			//button.setStyle("emphasizedPadding", event.value);
			StyleManager.setComponentStyle(Button,"emphasizedPadding", event.value);
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

UIComponent Button 01

2015. 12. 11. 15:35

ButtonTest_01.as

package {

import flash.display.Sprite;
import flash.display.StageAlign;
import flash.display.StageScaleMode;

import flash.events.Event;
import flash.events.MouseEvent;

import fl.controls.Button;

[SWF(backgroundColor = "#B4DCEB", width = "400", height = "150", frameRate = "12")]

public class ButtonTest_01 extends Sprite {

private var button: Button;

        public function ButtonTest_01() {
            stage.showDefaultContextMenu = false;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;

            button = new Button();
            button.name = "my_button";
            button.label = "button";
            button.x = centerAlign(stage.stageWidth, button.width);
            button.y = centerAlign(stage.stageHeight, button.height);
            addChild(button);

            button.addEventListener(MouseEvent.CLICK, clickHandler, false, 0, true);
        }

        private function clickHandler(event: MouseEvent): void {
            trace("the event occured on: " + event.target.name);
            trace("clickHandler detected an event of type: " + event.type);
        }

        private function centerAlign(param1: Number, param2: Number): int {
            return Math.round((param1 - param2) / 2);
        }
    }
}

ButtonTest_02.as

package {
	
	import fl.controls.Button;
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	
	import flash.events.Event;
	import flash.events.MouseEvent;
	
	[SWF(backgroundColor = "#B4DCEB", width = "400", height = "150", frameRate = "12")]
	
	public class ButtonTest_02 extends Sprite {
		
		private var button:Button;
		
		public function ButtonTest_02() {
			stage.showDefaultContextMenu = false;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			
			button = new Button();
			button.label = "button";
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			addChild(button);
			
			button.addEventListener(MouseEvent.MOUSE_OVER, mouseEventHandler, false, 0, true);
			button.addEventListener(MouseEvent.MOUSE_OUT, mouseEventHandler, false, 0, true);
			button.addEventListener(MouseEvent.MOUSE_DOWN, mouseEventHandler, false, 0, true);
			button.addEventListener(MouseEvent.MOUSE_UP, mouseEventHandler, false, 0, true);
		}
		
		private function mouseEventHandler(event:MouseEvent):void {
			txtEvent.text = event.type;
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

ButtonTest_03.as

package {
	
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	
	import flash.events.Event;
	import flash.events.MouseEvent;
	
	import fl.controls.Button;
	import flash.text.TextFormat;
	
	[SWF(backgroundColor = "#B4DCEB", width = "400", height = "150", frameRate = "12")]
	
	public class ButtonTest_03 extends Sprite {
		
		private var button:Button;
		private var isClick:Boolean;
		
		public function ButtonTest_03() {
			stage.showDefaultContextMenu = false;
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;
			
			button = new Button();
			button.label = "button";
			button.x = centerAlign(stage.stageWidth, button.width);
			button.y = centerAlign(stage.stageHeight, button.height);
			addChild(button);
			
			button.addEventListener(MouseEvent.CLICK, mouseClickHandler, false, 0, true);
		}
		
		private function mouseClickHandler(event:MouseEvent):void {
			if (!isClick) {
				var format:TextFormat = new TextFormat();
				format.size = 12;
			
				event.target.label = "button component";
				event.target.setSize(130, 28);
				event.target.x = centerAlign(stage.stageWidth, button.width);
				event.target.y = centerAlign(stage.stageHeight, button.height);
				event.target.setStyle("textFormat", format);
				isClick = true;
			}
		}
		
		private function centerAlign(param1:Number, param2:Number):int {
			return Math.round((param1 - param2) / 2);
		}
	}
}

PREV 1 2 NEXT